C----------------------------------------------------------------------- 
C $Id: fg_d.f,v 1.3 2005/03/22 00:30:22 andr Exp $
C
C Derivatives of muon decay spectrum from fg_1234.f with respect
C to Michel parameters.  
C
C Derived from fg_1234.f (v 1.7 2003/03/06 01:31:00)
C A.Gaponenko, 2003
C----------------------------------------------------------------------- 
C All Michel spectrum functions in this file return 0 if
C the energy argument x is outside of the [x0, 1] interval.
C  
C----------------------------------------------------------------------- 
      DOUBLE PRECISION FUNCTION DFDRHO(X,PARAM)
C     ---------------------------------------
      IMPLICIT NONE
      REAL*8 X, PARAM(8)
      REAL*8 AEM2, RHOM, ETAM, X0, FIS, WAC
      DFDRHO  = 0D0
      IF(X.LE.PARAM(8).OR.X.GE.1D0) RETURN

      AEM2  = PARAM(5)
      X0    = PARAM(8)
 
C.... EQ.(31) FROM KUNO&OKADA
      FIS   = 2D0/9D0*( 4D0*X**2 - 3D0*X - X0**2 )
      WAC   = (1D0+AEM2)**4*DSQRT(X**2-X0**2)*6D0
      DFDRHO  = FIS*WAC

      RETURN
      END
C----------------------------------------------------------------------- 
      DOUBLE PRECISION FUNCTION DFDETA(X,PARAM)
C     ---------------------------------------
      IMPLICIT NONE
      REAL*8 X, PARAM(8)
      REAL*8 AEM2, RHOM, ETAM, X0, FIS, WAC
      DFDETA  = 0D0
      IF(X.LE.PARAM(8).OR.X.GE.1D0) RETURN

      AEM2  = PARAM(5)
      X0    = PARAM(8)
 
C.... EQ.(31) FROM KUNO&OKADA
      FIS   = X0*(1D0-X)
      WAC   = (1D0+AEM2)**4*DSQRT(X**2-X0**2)*6D0

      DFDETA  = FIS*WAC
      RETURN
      END
C----------------------------------------------------------------------- 
      DOUBLE PRECISION FUNCTION DG_DXI_XIDELTA(X,PARAM)
C     ---------------------------------------
C.... BORN LEVEL F-FUNCTION WITH EXACT MASS DEPENDENCE
      IMPLICIT NONE
      REAL*8 X,Z,BETA,BET2,AEM2, CHIM, DELTAM, X0, FAS, WAC
      REAL*8 PARAM(8)
      DG_DXI_XIDELTA  = 0D0
      IF(X.LE.PARAM(8).OR.X.GE.1D0) RETURN

      AEM2  = PARAM(5)
      X0    = PARAM(8)
 
C.... EQ.(32) FROM KUNO&OKADA
      FAS   = 1D0/3D0*DSQRT(X**2-X0**2)*(1D0 - X)
      WAC   = (1D0+AEM2)**4*DSQRT(X**2-X0**2)*6D0

      DG_DXI_XIDELTA  = - FAS*WAC
      RETURN
      END
C----------------------------------------------------------------------- 
      DOUBLE PRECISION FUNCTION DG_DXIDELTA(X,PARAM)
C     ---------------------------------------
C.... BORN LEVEL F-FUNCTION WITH EXACT MASS DEPENDENCE
      IMPLICIT NONE
      REAL*8 X,Z,BETA,BET2,AEM2, CHIM, DELTAM, X0, FAS, WAC
      REAL*8 PARAM(8)
      DG_DXIDELTA  = 0D0
      IF(X.LE.PARAM(8).OR.X.GE.1D0) RETURN

      AEM2  = PARAM(5)
      X0    = PARAM(8)
 
C.... EQ.(32) FROM KUNO&OKADA
      FAS   = 1D0/3D0*DSQRT(X**2-X0**2)*(
     &      + 2D0/3D0*(4D0*X - 3D0
     &      + DSQRT(1D0-X0**2) - 1D0 ) )
      WAC   = (1D0+AEM2)**4*DSQRT(X**2-X0**2)*6D0

      DG_DXIDELTA  = - FAS*WAC
      RETURN
      END
C-----------------------------------------------------------------------